ndarray/CMakeLists.txt at master · 2018uch0002/ndarray · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
cmake_minimum_required(VERSION 3.11)

project(NDArray
  VERSION "0.1.0"
  DESCRIPTION "Numpy-like N-Dimentional array for C++"
  LANGUAGES CXX
)

# Get FetchContent for downloading dependencies
include(FetchContent)

#===============================================================================
# Get Boost
message(STATUS "Downloading Boost 1.81.0")
set(BOOST_INCLUDE_LIBRARIES container unordered)
set(BOOST_ENABLE_CMAKE ON)
FetchContent_Declare(Boost
  GIT_REPOSITORY https://github.com/boostorg/boost.git
  GIT_TAG        boost-1.81.0
)
FetchContent_MakeAvailable(Boost)

include(CMakePackageConfigHelpers)

# Add options
option(NDARRAY_INSTALL "Install NDArray" ON)

add_library(NDArray INTERFACE)
# Add alias to make more friendly with FetchConent
add_library(NDArray::NDArray ALIAS NDArray)

# Add public interface includes directory
target_include_directories(NDArray INTERFACE
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:include>
)

# Require C++11 standard
target_compile_features(NDArray INTERFACE cxx_std_11)

# Install NDArray
if(NDARRAY_INSTALL)
  include(GNUInstallDirs)

  configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/NDArrayConfig.cmake.in
    "${CMAKE_CURRENT_BINARY_DIR}/NDArrayConfig.cmake"
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NDArray
  )

  write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/NDArrayConfigVersion.cmake"
    VERSION "${NDArray_VERSION}"
    COMPATIBILITY SameMinorVersion
  )

  install(TARGETS NDArray
          EXPORT NDArrayTargets
          LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
          ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
          RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
          INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
  )

  install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/include/ndarray.hpp"
          DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

  install(EXPORT NDArrayTargets
          FILE NDArrayTargets.cmake
          NAMESPACE NDArray::
          DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NDArray
  )

  install(FILES
          "${CMAKE_CURRENT_BINARY_DIR}/NDArrayConfig.cmake"
          "${CMAKE_CURRENT_BINARY_DIR}/NDArrayConfigVersion.cmake"
          DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NDArray
  )
endif()